*************************************************************************
** HEALTHY EATING INDEX-2005                                           **
**                                                                     **
** This section of SAS code was taken from a program written by Lisa   **
** Kahle, Information Management Services, Inc.  It modifies the       **
** HEI-2005 for use with the NIH-AARP Diet and Health Study food       **
** frequency questionnaire. The NIH-AARP FFQ data was merged with the  **
** MyPyramid Equivalents Database to generate the MyPyramid            **
** Equivalents variables.                                              **
**                                                                     **
**                                                                     **
*************************************************************************;


**CALORIES FROM SOLID FAT, ALCOHOL, AND ADDED SUGAR (SOFAAS) VARIABLE**; **CODE TO CREATE VARIABLES FOR CALORIES FROM ADDED SUGAR, CALORIES FROM SOLID FAT, AND CALORIES FROM DRINKS OF ALCOHOL.  SUM TOGETHER TO CREATE A VARIABLE THAT REPRESENTS ALL EXTRA CALORIES.**;

  ADDSUGC=4.2*4*MPED_ADD_SUG;
  ADDFATC=9*MPED_DISCFAT_SOLID;
  ALCOHOLC=(MPED_A_BEER *153)+ (MPED_A_LIQUOR*97) + (MPED_A_WINE*124);

  EXTRAC=ADDSUGC+ADDFATC+ALCOHOLC;

**LEGUMES CALCULATION**;
**CODE TO COUNT LEGUMES AS MEAT AND BEANS UNTIL THE STANDARD IS MET, THEN THE REST COUNT TOWARD VEGETABLES.**;

* CALC TOT MEAT SERVINGS;
  ALLMEAT=MPED_M_MPF+MPED_M_EGG+MPED_M_NUTSD+MPED_M_SOY;

* MEAT MAXIMUM - AMOUNT NEEDED FOR HIGHEST HEI SCORE;
  MBMAX=2.5*(CALORIES/1000);

IF ALLMEAT < MBMAX THEN DO; 		*IF NOT ENOUGH MEAT CONSUMED;
   MEATLEG=MPED_LEGUMES*4;  	    	*CONVERT LEGUME IN VEG TO MEAT EQUIV OZ;
   NEEDMEAT=MBMAX-ALLMEAT;  		*AMOUNT NEEDED TO REACH MAXIMUM SCORE;
   IF MEATLEG <= NEEDMEAT THEN DO; 	*ALL LEG GO TO MEAT;
      LEGTYPE='ALLMEAT ';
      ALLMEAT=ALLMEAT+MEATLEG;
      MPED_V_TOTAL=MPED_V_TOTAL;
      MPED_V_DOL=MPED_V_ORANGE+MPED_V_DRKGR;
   END;
   ELSE IF MEATLEG > NEEDMEAT THEN DO; 	*SOME LEG TO MEAT/ REST TO VEG;
      LEGTYPE='MEAT/VEG';
      EXTRMEAT=MEATLEG-NEEDMEAT;
      EXTRLEG=EXTRMEAT/4;             *CONVERT MEAT EQUIV BACK TO VEG SERV;
      ALLMEAT=ALLMEAT+NEEDMEAT;       *SOME GOES TO MEAT;
      MPED_V_TOTAL=MPED_V_TOTAL+EXTRLEG;         	*REST GOES TO VEG;
      MPED_V_DOL=MPED_V_ORANGE+MPED_V_DRKGR+EXTRLEG;
   END;
END;
  ELSE IF ALLMEAT >= MBMAX THEN DO;   			* ALL LEG GO TO VEG;
    LEGTYPE='ALLVEG  ';
    MPED_V_TOTAL=MPED_V_TOTAL+MPED_LEGUMES;
    MPED_V_DOL=MPED_V_ORANGE+MPED_V_DRKGR+MPED_LEGUMES;
  END;

**END OF LEGUME CODE**;

**CODE TO CREATE DAILY DENSITY - AMOUNT PER 1000 KCAL – FOR EACH COMPONENT**;

  FRTDEN=MPED_F_TOTAL/(CALORIES/1000);
  WHFRDEN=MPED_F_NOJUICE/(CALORIES/1000);
  VEGDEN=MPED_V_TOTAL/(CALORIES/1000);
  DGVDEN=MPED_V_DOL/(CALORIES/1000);
  GRNDEN=MPED_G_TOTAL/(CALORIES/1000);
  WGRNDEN=MPED_G_WHL/(CALORIES/1000);
  MEATDEN=ALLMEAT/(CALORIES/1000);
  OILDEN=MPED_DISCFAT_OIL/(CALORIES/1000);
  DAIRYDEN=MPED_D_TOTAL/(CALORIES/1000);
  SODDEN=SODIUM/(CALORIES/1000);
*GET PERCENT CAL FROM;
  SFAT_PERC=100*(FATSATURATED*9)/CALORIES;
  SOFAAS_PERC=100*(EXTRAC/CALORIES);

**CODE TO CALCULATE HEI-2005 COMPONENTS**;

HEI1=5*(FRTDEN/.8);
IF HEI1 > 5 THEN HEI1=5;

HEI2=5*(WHFRDEN/.4);
IF HEI2 > 5 THEN HEI2=5;

HEI3=5*(VEGDEN/1.1);
IF HEI3 > 5 THEN HEI3=5;

HEI4=5*(DGVDEN/.4);
IF HEI4 > 5 THEN HEI4=5;

HEI5=5*(GRNDEN/3);
IF HEI5 > 5 THEN HEI5=5;

HEI6=5*(WGRNDEN/1.5);
IF HEI6 > 5 THEN HEI6=5;

HEI7=10*(DAIRYDEN/1.3);
IF HEI7 > 10 THEN HEI7=10;

HEI8=10*(MEATDEN/2.5);
IF HEI8 > 10 THEN HEI8=10;

HEI9=10*(OILDEN/12);
IF HEI9 > 10 THEN HEI9=10;

*SODIUM;
SODMAX=2000;
SODMED=1100;
SODMIN=700;
IF SODDEN >= SODMAX THEN HEI10=0;
  ELSE IF SODDEN <= SODMIN THEN HEI10=10;
  ELSE IF SODDEN >= SODMED THEN
      HEI10= 8 - ( 8 * (SODDEN-SODMED)/(SODMAX-SODMED) );
  ELSE HEI10= 10 - (2 * (SODDEN-SODMIN)/(SODMED-SODMIN) );

*% CAL SAT FAT;
SFATMAX=15;
SFATMED=10;
SFATMIN=7;
IF SFAT_PERC >= SFATMAX THEN HEI11=0;
  ELSE IF SFAT_PERC <= SFATMIN THEN HEI11=10;
  ELSE IF SFAT_PERC > SFATMED THEN
      HEI11= 8 - ( 8 * (SFAT_PERC-SFATMED)/(SFATMAX–SFATMED) );
  ELSE HEI11= 10 - (2 * (SFAT_PERC–SFATMIN)/ (SFATMED–SFATMIN) );

*EXTRAC;
SOFAASMIN=20;
SOFAASMAX=50;
IF SOFAAS_PERC >= SOFAASMAX THEN HEI12=0;
  ELSE IF SOFAAS_PERC <= SOFAASMIN THEN HEI12=20;
  ELSE HEI12= 20 - ( 20* (SOFAAS_PERC-SOFAASMIN) / (SOFAASMAX-SOFAASMIN) );
 
**CALCULATE HEI-2005 TOTAL SCORE**;
**CODE TO SUM THE 12 HEI-2005 COMPONENT SCORES**;

TOTSCORE_HEI=HEI1+HEI2+HEI3+HEI4+HEI5+HEI6+HEI7+HEI8+HEI9+HEI10+HEI11+HEI12;

LABEL TOTSCORE_HEI='TOTAL SCARE OF 12 HEI COMPONENTS'
      HEI1='HEI COMPONENT TOTAL FRUIT'
	  HEI2='HEI COMPONENT NON-JUICE FRUIT'
	  HEI3='HEI COMPONENT TOTAL VEGETABLES'
	  HEI4='HEI COMPONENT DARK GREEN AND ORANGE VEG & LEGUMES'
	  HEI5='HEI COMPONENT TOTAL GRAINS'
	  HEI6='HEI COMPONENT WHOLE GRAINS'
	  HEI7='HEI COMPONENT MILK INCLUDING SOY BEV'
	  HEI8='HEI COMPONENT MEAT & BEANS'
	  HEI9='HEI COMPONENT OILS'
	  HEI10='HEI COMPONENT SODIUM'
	  HEI11='HEI COMPONENT SATURATED FAT'
	  HEI12='HEI COMPONENT SOLID FAT, ALCOHOL AND ADDED SUGAR';