#!/bin/csh -bf
#
# gp.postbreak
#
# Script to run Postbreak.
#
# 1995/10/15 whp Adapted from runall processing for gp processing
# Modifications: 19990302 jls Added check for SolveLimit
#                20000121 jls Added if around postbreak. If
#                             working with Track set flag for cycle slips
#                             at 10 cm all others will be flagged at
#                             5 cm.


#  Check number of arguments
#  -------------------------
   echo " "
   if ($#argv != 0) then
      echo Usage:  gp.postbreak
      exit 1
   endif

   set Campaign_Name = `gp.CreateCampaignPrefix`

#  Postbreak
#  ---------
   rm batch.text.new qmfile.new >& /dev/null

   if ($Campaign_Name == "Track") then
   nice postbreak -auto -p postfit.nio \
                  -b batch.txt \
                  -o batch.txt.new \
                  -n /goa/local/templates/postbreak.nml \
                  -qi qmfile \
                  -qo qmfile.new \
                  -arc 1200 \
                   >& postbreak.log
   else if ($Campaign_Name == "LandersPro") then
   nice postbreak -p postfit.nio \
                  -b batch.txt \
                  -o batch.txt.new \
                  -n /goa/local/templates/camp.nml \
                  -qi qmfile \
                  -qo qmfile.new \
                   >& postbreak.log
   else
   nice postbreak -p postfit.nio \
                  -b batch.txt \
                  -o batch.txt.new \
                  -qi qmfile \
                  -qo qmfile.new \
                  -arc 1200 \
                   >& postbreak.log
   endif

   grep "pts in arcs" postbreak.log


#  Update batch.txt and qmfile for next loop
#  -----------------------------------------
   set SolveLimit = `grep SolveLimit ProcessFlags | awk '{print $2}'`
   if ($SolveLimit != 1) then
      if ( -e batch.txt.new ) then
         rm batch.txt >& /dev/null
         mv batch.txt.new  batch.txt
      endif
      if ( -e qmfile.new ) then
         rm qmfile >& /dev/null
         mv qmfile.new qmfile
      endif
   endif

#  Check for errors
#  ----------------
   if (-e core) then
      rm core
   endif
   if (! -e postbreak.log) then
      echo "gp.postbreak: postbreak output file postbreak.log not found."
      exit 1
   endif