#!/bin/csh -bf
#
#  gp.filter
#
#  Script to run PREPREFILTER, PREFILTER, and FILTER.
#  N.E. King
#  August 1994
#
#  Modifications:
#  March 1995 Modified to use wash_nml (GIPSY R3)
#  1995/10/15 whp Adapted to process both continuous and survey data.


#  CHECK NUMBER OF ARGUMENTS
#  -------------------------
echo " "
if ($#argv != 0) then
   echo Usage:  gp.filter
   exit 1
endif

set point = `grep PointPosition ProcessFlags | awk '{print $2}'`


# CREATE WASH.NML, IF NECESSARY
# (Fiducials are also handled here)
# ---------------------------------
   if (! -e wash.nml) then
      gp.wash_nml
   endif

#  preprefilter
#  ------------
echo " "
rm prefilter.txt >& /dev/null
nice preprefilter wash.nml       rgfile \
                  prefilter.txt  >& preprefilter.log
if (-e core) then
   rm core
endif


#  prefilter
#  ---------
rm  batch.txt phase.txt >& /dev/null
nice prefilter prefilter.txt  rgfile \
               batch.txt      phase.txt \
               >& prefilter.log
if (-e core) then
   rm core
endif


#  Filter
#  ------
rm  accume.nio smooth.nio oi.nio >& /dev/null
nice filter batch.txt  wash.nml \
            no_oi     rgfile \
            accume.nio smooth.nio \
            uinv.nio   >& filter.log


# CHECK FOR ERRORS
# ----------------
if (-e core) then
   rm core
endif
if (! -e accume.nio) then
   echo "gp.filter: filter output file accume.nio not found."
   exit 1
endif