#!/bin/csh -bf
#
#  GetLocalData
#
#  1995/08/14 Created by N.E. King
#  1995/08/24 Modified by N.E. King, to use no arguments
#                                    /goa/sta_info/NameTrans file
#  1995/09/05 Modified by N.E. King, to use NameTrans file in its new form
#  1995/09/06 Modified to N.E. King, to use sub-script GetData.ChangeFilename
#  1995/09/22 Modified to N.E. King, to use sub-scripts GetData.(stnd2jpl ChangeName),
#                                    use new USGS standard file names,
#                                    remove variable file naming convention

#  Verify existence of SaveObsDate
#  -------------------------------
   if (! -e SaveObsDate) then
      echo GetLocalData: SaveObsDate not found. Script stops.
      echo "              Run CreateObsDateFile first."
      exit 1
   endif

#  Verify existence of GetLog
#  --------------------------
   if (! -e GetLog) then
      echo GetLocalData: File GetLog not found. Script stops.
      echo "              Run CreateGetLog first."
      exit 1
   endif

#  Verify existence of NameTrans
#  --------------------------------
   if (! -e /goa/sta_info/NameTrans) then
      echo GetLocalData: File /goa/sta_info/NameTrans not found. Script stops.
      exit 1
   endif

#  Set date and path strings
#  -------------------------
   set datelong = `grep datelong SaveObsDate | awk '{print $2}'`
   set dateshort = `grep dateshort SaveObsDate | awk '{print $2}'`
   set longyr = `grep longyr SaveObsDate | awk '{print $2}'`
   set yymm = `grep yymm SaveObsDate | awk '{print $2}'`
   set yrobs = `grep yrobs SaveObsDate | awk '{print $2}'`
   set doy = `grep doy SaveObsDate | awk '{print $2}'`
   set pathname = /GPSdata/rinex/$longyr/$yymm/$dateshort

#  Try to get all stations from /attic. 
#  ------------------------------------
   set stalist = `awk '{print $1}' GetLog`
   @ i=1
   while ($i <= $#stalist)
      cp $pathname/$stalist[$i]*o.Z . >& /dev/null
      @ i=$i + 1
   end
 
#  Uncompress files.
#  Change file names to JPL form, with appropriate receiver type tags.
#  -------------------------------------------------------------------
   uncompress -f *.Z
   GetData.usgs2jpl

#  Change to canonical station names, if necessary.
#  In GetLog, change havenot to have for canonical names and all alternates.
#  -------------------------------------------------------------------------
   GetData.ChangeNames