/********************************************************************\

PROGRAM:        C:\\MEPS\PROG\EXAMPLE02.SAS

DESCRIPTION:  	THIS EXAMPLE SHOWS THE NEED FOR USING THE
		         STRATUM AND PSU VARIABLES WHEN ANALYZING MEPS 
		         DATA FOR NATIONAL ESTIMATES.  THAT IS, TAKING
		         THE MEPS COMPLEX DESIGN PROPERTIES INTO
		         ACCOUNT.

INPUT FILE:  	C:\MEPS\DATA\H79.SAS7BDAT (2003 FULL-YEAR DATA FILE)

\********************************************************************/

FOOTNOTE 'PROGRAM: C:\MEPS\PROG\EXAMPLE02.SAS';

LIBNAME CDATA V8 'C:\MEPS\DATA' ;

TITLE1 'AHRQ MEPS DATA USERS WORKSHOP -- JULY 2006';
TITLE2 'EFFECT OF STRATA AND PSU VARIABLES ON COMPUTING';
TITLE3 'STANDARD ERRORS FOR TOTAL HEALTH-CARE EXPENDITURES';

DATA PUF79 ;
	SET CDATA.H79 (KEEP= TOTEXP03 VARPSU VARSTR PERWT03F);
RUN;

/***** ASSUME SIMPLE RANDOM SAMPLE *****/

PROC SURVEYMEANS DATA= PUF79 NOBS SUM  ;
	WEIGHT PERWT03F ;
	VAR TOTEXP03 ;
	ODS OUTPUT STATISTICS= SRSTOT (KEEP= SUM STDDEV) ;
RUN;

/***** ACCOUNT FOR MEPS COMPLEX SAMPLE DESIGN *****/

PROC SURVEYMEANS DATA= PUF79 NOBS SUM  ;
	STRATUM VARSTR ;
	CLUSTER VARPSU ;
	WEIGHT PERWT03F ;
	VAR TOTEXP03 ;
	ODS OUTPUT STATISTICS= COMPTOT (KEEP= SUM STDDEV);
RUN;

DATA _NULL_;
	SET SRSTOT;
	PUT 'SRS    TOTAL IS ' SUM DOLLAR19.2 ;
	PUT 'SRS SE TOTAL IS ' STDDEV DOLLAR19.2 ;
RUN;

DATA _NULL_;
	SET COMPTOT;
	PUT 'COMPLEX DESIGN TOTAL    IS ' SUM DOLLAR19.2 ;
	PUT 'COMPLEX DESIGN TOTAL SE IS ' STDDEV DOLLAR19.2 ;
RUN;