program heat_dy_read
c
c This program reads daily or hourly TAO/TRITON and PIRATA ascii 
c   format heat files for example heat0n110w_dy.ascii. It creates 
c   real time series arrays which are evenly spaced in time.
c
c Also created are integer arrays of data quality.
c
c You can easily adapt this program to your needs.
c
c Programmed by Dai McClurg, NOAA/PMEL/OCRD
c
      implicit none
c
      integer nt
      parameter(nt = 100000)
c
      integer n, m
c
      integer nblock, nn, ntime, n1, n2
c
      integer idate(nt), ihms(nt)
      integer iqheat(nt)
c
      real heat(nt), depheat
      real flag
c
      character infile*80, header*132, line*132
c
c .......................................................................
c
      write(*,*) ' Enter the input heat file name '
      read(*,'(a)') infile
c
      open(1,file=infile,status='old',form='formatted')
c
c Read total number of hours and blocks of data.
c

      read(1,10) ntime, nblock
   10 format(49x,i5,7x,i3)
c
      write(*,*) ntime, nblock
c
c Read the missing data flag
c
      read(1,20) flag
   20 format(45x,f6.3)
c
      write(*,*) flag
c
c  Initialize data arrays to flag and quality arrays to 5.
c
      do n = 1, nt
          heat(n) = flag
        iqheat(n) = 5
      enddo
c
c Read the data.
c
      do m = 1, nblock
        read(1,30) n1, n2, nn
        read(1,'(a)') line
        read(line(12:22),*) depheat
        read(1,'(a)') header
        do n = n1, n2
          read(1,60) idate(n), ihms(n), heat(n), iqheat(n)
        enddo
      enddo
c
   30 format(51x,i5,4x,i5,1x,i5)
   60 format(1x,i8,1x,i4,1x,f6.3,1x,i1)
c
      close(1)
c
c Now write out the data and quality arrays to the standard output.
c
      write(*,*) depheat
c
      do n = 1, ntime
        write(*,60) idate(n), ihms(n), heat(n), iqheat(n)
      enddo
c
      end