*****************************************************************************
*The SAS program (HEI2005_NHANES0102_PopulationScore.sas):		    *
*									    *
*This program creates the component and total scores of the HEI-2005	    * 
*for a population or a group.						    *
*The 12 components include: Total Fruit, Whole Fruit, 	      	   	    *	
*Total Vegetables, Dark Green and Orange Vegetables and Legumes,    	    *	
*Total Grains, Whole Grains, Milk, Meat and Beans, Oils,    		    *
*Saturated Fat, Sodium, and 				      		    *
*Calories from Solid Fat, Alcohol, and Added Sugar (SoFAAS). 		    *
*Please see readme file at http://www.cnpp.usda.gov/HealthyEatingIndex.htm  *
*****************************************************************************;

/* Libname is the location of the input datasets.  
See http://www.sas.cc.vt.edu/faqlib/libname.html 
for more information*/

LIBNAME HEI "C:\";

TITLE 'NHANES 2001-2002, AGE >= 2, RELIABLE DIETS, Include Pregnant and Lactating Women';

OPTIONS LINESIZE=79;

/*Section (I): Calculation of food group, nutrient, and energy intakes at the individual 
participant level.*/

/*Step 1: locate 3 required datasets*/
/*MyPyrEquivDB_v1:MyPyramid Equivalents Database for USDA Survey Food Codes Version 1.0
CNPPMyPyrEquivDB_v1_WJFRT: CNPP MyPyramid Equivalent Database for Whole Fruit and Fruit Juice 
drxiff_b: NHANES 2001-2002 individual food intake data for 1 day
drxtot_b: NHANES 2001-2002 individual nutrient intake data in 1 day
demo_b:NHANES 2001-2002 individual demographic and survey sampling information
*/

data MPED;
 set HEI.MyPyrEquivDB_v1;

  /*In the HEI-2005, soy beverages are counted as part of the Milk component.  
 Convert the four soy beverage codes in the MPED from M_SOY oz equivalents to D_TOTAL cup 
 equivalents using the following conversion process based on FNDDS 1.0*/

  /*FOODCODE=11310000, MILK, IMITATION, FLUID, SOY BASED (1 cup=244 grams)
    FOODCODE=11320000, MILK, SOY, READY-TO-DRINK, NOT BABY (1 cup=245 grams)
    FOODCODE=11321000, MILK, SOY, READY-TO-DRINK, NOT BABY'S, CHOCOLATE (1 cup=240 grams)
    FOODCODE=11330000, MILK, SOY, DRY, RECONSTITUTED, NOT BABY (1 cup=245 grams)*/

  IF FOODCODE=11310000 THEN DO;
     M_SOY=0;
	 D_TOTAL=ROUND(100*(1/244),.001);
	 END;
  ELSE IF FOODCODE=11320000 THEN DO;
     M_SOY=0;
	 D_TOTAL=ROUND(100*(1/245),.001);
	 END;
  ELSE IF FOODCODE=11321000 THEN DO;
     M_SOY=0;
	 D_TOTAL=ROUND(100*(1/240),.001);
	 END;
  ELSE IF FOODCODE=11330000 THEN DO;
     M_SOY=0;
	 D_TOTAL=ROUND(100*(1/245),.001);
	 END;
run;
PROC SORT DATA=MPED;
  BY FOODCODE;
run;

DATA CNPPMPED_WJFRT;
  SET HEI.CNPPMyPyrEquivDB_v1_WJFRT /*fruitjuice0102*/;
run;
PROC SORT DATA=CNPPMPED_WJFRT;
  BY FOODCODE;
run;

DATA Food;                           
  SET HEI.drxiff_b;
  FOODCODE=1*DRDIFDCD; /*convert variable name and type*/
  if DRDDRSTZ=1; /*reliable dietary recall status*/
RUN;
PROC SORT DATA=Food;
  BY FOODCODE;
run;

/*Use the individual's Day 1 dietary intake sample weight (WTDRD1) accounts for 
the survey sample design, nonresponse rate, and propotion of intake days 
(on weekdays or weekend days). It can be downloaded from 
http://www.cdc.gov/nchs/about/major/nhanes/exam01_02.htm*/

DATA Nutrient (keep=seqn WTDRD1 DRXTKCAL DRXTCARB DRXTSFAT DRXTALCO DRDTSODI);
  SET HEI.DRXTOT_b;
  if DRDDRSTZ=1; /*reliable dietary recall status*/
run;
PROC SORT DATA=Nutrient;
  BY SEQN;
run;

DATA demo (keep=seqn RIDAGEYR RIAGENDR SDDSRVYR SDMVPSU SDMVSTRA);
  SET HEI.demo_b;
run;
PROC SORT DATA=demo;
  BY SEQN;
run;

/*Step 2: Combine the required datasets and calculate NHANES 2001-2002 
individual food group and nutrient intakes*/

DATA PYR;
  MERGE MPED(IN=S) CNPPMPED_WJFRT(IN=N);
  BY FOODCODE;
  IF S AND N;
run;

DATA FDPYR;
  MERGE Food (IN=S) PYR (IN=N);
  BY FOODCODE;
  IF S AND N;
run;

/*Convert NHANES 01-02 individuals' food intake amounts from grams to 
MyPyramid equivalents*/

DATA FDPYR;
  SET FDPYR;

/*Calculate intake for MyPyramid food groups*/  

 ARRAY PYRVAR F_TOTAL WHOLEFRT V_TOTAL V_DRKGR V_ORANGE 
			  LEGUMES G_TOTAL G_WHL D_TOTAL M_MPF 
			  M_EGG M_NUTSD M_SOY DISCFAT_OIL DISCFAT_SOL
			  ADD_SUG;

 DO OVER PYRVAR;
    PYRVAR=PYRVAR*(DRXIGRMS/100);
 END;

run;

PROC SORT DATA=FDPYR;
  BY SEQN;
run;

/*Calculate individual's food intake amounts for MyPyramid food groups in 1 day*/
PROC MEANS DATA=FDPYR NOPRINT;
  BY SEQN;
  VAR F_TOTAL WHOLEFRT V_TOTAL V_DRKGR V_ORANGE LEGUMES G_TOTAL G_WHL D_TOTAL M_MPF 
	  M_EGG M_NUTSD M_SOY DISCFAT_OIL DISCFAT_SOL ADD_SUG;
  OUTPUT OUT=PYRCALC SUM= ;
run;

/*Individual's nutrient intake (DRXICARB, carbohydrate; DRXIALCO, alcohol) from beer, wine 
and distilled spirits, but exclude cooking wine*/
DATA BWLNUT (KEEP=SEQN DRXICARB DRXIALCO DRXILINE THREED);                           
  SET food;
  THREED=INT(FOODCODE/100000);
  IF (931 <= THREED <= 935);	/*alcoholic beverages of beer, wine, and distilled spirits*/
  
  IF FOODCODE=93401300 THEN DELETE; /*Remove cooking wine*/
run;
PROC SORT DATA=BWLNUT;
  BY SEQN DRXILINE;
run;

/*Identify Added Sugar intake from beer, wine 
and distilled spirits, but exclude cooking wine*/
DATA BWLPYR (KEEP=SEQN ADD_SUG DRXIGRMS DRXILINE THREED);                           
  SET FDPYR;
  THREED=INT(FOODCODE/100000);
  IF (931 <= THREED <= 935);	/*alcoholic beverages of beer, wine, and distilled spirits*/
  
  IF FOODCODE=93401300 THEN DELETE; /*Remove cooking wine*/
run;
PROC SORT DATA=BWLPYR;
  BY SEQN DRXILINE;
run;

DATA BEERWINELIQ;
  MERGE BWLNUT BWLPYR;
  BY SEQN DRXILINE;
run;

/*Exclude calories from Added Sugars food group in alcoholic beverages*/
DATA BEERWINELIQ;
  SET BEERWINELIQ;
  BY SEQN;

  SUGGRAM=ADD_SUG*4; 	/*convert from teaspoons to grams of added sugars=grams of carbohydrate from added sugars*/
  NOSCARB=DRXICARB-SUGGRAM;	/*subtract grams of carbohydrate from added sugars from the total carbohydrate*/
  IF THREED IN (931,932,934) THEN BWCARBC=NOSCARB*4;	/*SoFAAS calories from carbohydrate in alcoholic beverages*/
  ETHCAL=DRXIALCO*7; /*SoFAAS calories from alcohol (ethanol) in alcoholic beverages*/
run;

/*Calculate individual's SoFAAS calories from carbohyrdate and alcohol (ethanol) in alcoholic beverages in 1 day*/
PROC MEANS DATA=BEERWINELIQ NOPRINT;
  BY SEQN;
  VAR BWCARBC ETHCAL;
  OUTPUT OUT=BEERWINELIQ SUM=BWCARBC ETHCAL;
run;

/*Combine all required datasets*/
/*Only include individuals who are age 2 years and older*/
/*Exclusion criteria change (9/17/07): include all preg and lactation women*/
DATA BOTH;
  MERGE Nutrient (IN=F) BEERWINELIQ PYRCALC(IN=P) DEMO;
  BY SEQN;
  IF F AND P;
  IF RIDAGEYR >= 2;		/*individuals age 2 and older*/
run;

/*Step 3: Calculate food group and nutrient intakes 
at the individual level*/

/*Please note: MyPyramid equivalent values for total vegetable intake (V_TOTAL) in the HEI-2005
  may be different from V_TOTAL in the MPED because legumes may be counted as vegetables or meat
  in the HEI-2005; and total dairy intake (D_TOTAL) in the HEI-2005 may be different from D_TOTAL 
  in the MPED because soy beverages are counted as milk in the HEI-2005.*/

DATA HEI2005POP;
  SET BOTH;
  BY SEQN;

/**Calculate HEI-2005 Meat and Beans intake**/
/*Standard is 2.5 oz equiv/1000 kcal*/

ALLMEAT=M_MPF+M_EGG+M_NUTSD+M_SOY;	/*Calculate total meat intake from meat, poultry, & fish; egg; nuts and seeds; soy products*/
MBMAX=2.5*(DRXTKCAL/1000);	/*Create the Meat and Beans standard*/

 /*Legumes intake calculation*/
 /*Legumes intake counts as Meat and Beans until the standard is met, then the rest count as Total Vegetables*/

/*(a) If total meat intake is less than the Meat and Beans recommendation then 
  all Legumes go to Meat and Beans*/
IF ALLMEAT < MBMAX THEN DO;
   MEATLEG=LEGUMES*4;	/*Convert cup equivalents of Legumes to oz equivalents */
   NEEDMEAT=MBMAX-ALLMEAT;

   IF MEATLEG <= NEEDMEAT THEN DO;
      LEGTYPE='ALLMEAT ';
      ALLMEAT=ALLMEAT+MEATLEG;
      V_TOTAL=V_TOTAL;
      V_DOL=V_ORANGE+V_DRKGR;
   END; 

/*(b) Some Legumes go to Meat and Beans and the rest goes to Total Vegetables*/
   ELSE IF MEATLEG > NEEDMEAT THEN DO; 
      LEGTYPE='MEAT/VEG';
      EXTRMEAT=MEATLEG-NEEDMEAT;
      EXTRLEG=EXTRMEAT/4; 	/*Convert oz equivalents of Meat and Beans from Legumes back to cup equivalents*/
	  ALLMEAT=ALLMEAT+NEEDMEAT;
	  V_TOTAL=V_TOTAL+EXTRLEG;
	  V_DOL=V_ORANGE+V_DRKGR+EXTRLEG;
     END;
END; 

/*(c) If total meat intake exceeds the Meat and Beans standard, then all Legumes count as Total Vegetables*/
ELSE IF ALLMEAT >= MBMAX THEN DO;  
    LEGTYPE='ALLVEG';
    V_TOTAL=V_TOTAL+LEGUMES;
	V_DOL=V_ORANGE+V_DRKGR+LEGUMES;
END;

/*Redefine Total Vegetables consumption after Meat and Bean intake calculation process*/
VEGCUP=V_TOTAL;

/*Redefine Dark Green and Orange Vegetables and Legume consumption after Meat and Bean intake calculation process*/
DGOCUP=V_DOL;

/**Calculate intake of Calories from SoFAAS**/

 /*Calculate SoFAAS Calories from Added sugars, solid fat, and alcoholic beverages*/
  ADDSUGC=16*ADD_SUG;		/*calories from added sugars*/
  SOLFATC=DISCFAT_SOL*9;	/*calories from solid fat*/
  
  IF ETHCAL < 0 THEN ETHCAL=0;
  IF BWCARBC < 0 THEN BWCARBC=0;
  EXFAAS=ADDSUGC+SOLFATC+ETHCAL+BWCARBC; /*total SoFAAS calories as in kcal*/
  
run;

/*Section (II): Calculation of ratios of mean food group and nutrient intakes to mean energy intakes at the population level.  */

/**Population ratio for the HEI-2005 components=

	Sum of weighted population food or nutrient consumption
	------------------------------------------------------- 
	Sum of weighted total kcal consumption 						*/

/*Convert food group and nutrient intakes in density unit based on HEI-2005 components*/
data POP0102;
 set HEI2005POP;
 F_TOTAL1000 =F_TOTAL*1000;
 WHOLEFRT1000 =WHOLEFRT*1000;
 VEGCUP1000 =VEGCUP*1000;
 DGOCUP1000 =DGOCUP*1000;
 G_TOTAL1000 =G_TOTAL*1000;
 G_WHL1000 =G_WHL*1000;
 D_TOTAL1000 =D_TOTAL*1000;
 ALLMEAT1000 =ALLMEAT*1000;
 DISCFAT_OIL1000 =DISCFAT_OIL*1000;
 DRXTSFATper =DRXTSFAT*9*100;
 DRDTSODIgm1000 =DRDTSODI*1000/1000;
 EXFAASper =EXFAAS*100;
run; 

/*Population ratio estimates for the HEI-2005 components, age 2+*/
proc sort data=POP0102; by SDMVSTRA SDMVPSU ; run;
proc ratio data=POP0102 design=wr filetype=sas;
NEST SDMVSTRA SDMVPSU ;
weight WTDRD1;
numer F_TOTAL1000 WHOLEFRT1000 VEGCUP1000 DGOCUP1000 G_TOTAL1000 
		G_WHL1000 D_TOTAL1000 ALLMEAT1000 DISCFAT_OIL1000 DRXTSFATper  
		DRDTSODIgm1000 EXFAASper;
denom DRXTKCAL DRXTKCAL DRXTKCAL DRXTKCAL DRXTKCAL DRXTKCAL DRXTKCAL
		DRXTKCAL DRXTKCAL DRXTKCAL DRXTKCAL DRXTKCAL;
Setenv Labwidth=15 rowspce=0 colspce=2;
Print nsum="samzie" wsum="popsize" wxsum="total wted kcal" wysum="total wted intake" 
		rhat="Prop. of intake" serhat="S.E. of Prop." lowrhat="lower 95%" uprhat="upper 95%"
		/nsumfmt=f15.0 wsumfmt=f15.0 wxsumfmt=f15.0 wysumfmt=f15.0 rhatfmt=f7.4 serhatfmt=f7.5 lowrhatfmt=f12.5 uprhatfmt=f12.5 style=NCHS;
title "NHANES 2001-2002, population ratio of intakes (sum food/sum kcal), 
		age 2+ ";
output nsum rhat serhat lowrhat uprhat/
		filename=ratio0102 rhatfmt=f7.4 serhatfmt=f7.5 lowrhatfmt=f7.5 uprhatfmt=f7.5 replace;
run;

/*Section (III): Calculation of the HEI-2005 component and total scores at the population level*/

/**Export the output from SUDAAN into an Excel worksheet (popratio0102.xls) and then calculate the 
HEI-2005 component and total scores in a different Excel worksheet
by copying the output (RHAT and SERHAT) into the yellow highlighted cells in the Excel worksheet, 
HEI2005_NHANES 2001-2002PopScores.xls*/

proc export data=ratio0102 outfile="C:\popratio0102.xls"
dbms=excel replace; run;

/*Section (IV):	Calculation of the standard error of the population total HEI-2005 score*/

/*Create non-trucated HEI-2005 component and total scores at individual level*/
/*Create a dataset to calculate the standard error for the total HEI-2005 score of a population or a group*/
DATA HEI2005POP_0102SE_notrun;
  SET BOTH;
  BY SEQN;

/**Calculate HEI-2005 TOTAL FRUIT non-truncated component score**/
/*Standard for maximum score is >=0.8 cup equiv/1000 kcal;
  no Fruit intake, minimum score is zero*/

FMAX=.8*(DRXTKCAL/1000);
HEI1=5*(F_TOTAL/FMAX);
IF F_TOTAL=0 THEN HEI1=0;

/**Calculate HEI-2005 WHOLE FRUIT non-truncated component score**/
/*Standard for maximum score is >=0.4 cup equiv/1000 kcal;
  no Fruit intake, minimum score is zero*/
NJFMAX=.4*(DRXTKCAL/1000);
IF NJFMAX > 0 THEN HEI2=5*(WHOLEFRT/NJFMAX);
IF F_TOTAL=0 THEN HEI2=0;

/**Calculate HEI-2005 Total Grains non-truncated component score**/
/*Standard for maximum score is >=3.0 cup equiv/1000 kcal;
  no Total Grains intake, minimum score is zero*/
GMAX=3.0*(DRXTKCAL/1000);
IF GMAX > 0 THEN HEI5=5*(G_TOTAL/GMAX);

/**Calculate HEI-2005 Whole Grains non-truncated component score**/
/*Standard for maximum score is >=1.5 cup equiv/1000 kcal;
  no Whole Grains intake, minimum score is zero*/
WGMAX=1.5*(DRXTKCAL/1000);
IF WGMAX > 0 THEN HEI6=5*(G_WHL/WGMAX);

IF G_TOTAL=0 THEN DO;  /*no reported Total Grains intake, Total Grains and Whole Grains component scores are zero*/
  HEI5=0; HEI6=0;
END;

/**Calculate HEI-2005 Milk non-truncated component score**/
/*Standard for maximum score is >=1.3 cup equiv/1000 kcal;
  no Milk intake, minimum score is zero*/
DAIRYMAX=1.3*(DRXTKCAL/1000);
HEI7=10*(D_TOTAL/DAIRYMAX);

/**Calculate HEI-2005 Meat and Beans non-truncated component score**/
/*Standard for maximum score is >=2.5 oz equiv/1000 kcal;
  no Mean or Beans intake, minimum score is zero*/

ALLMEAT=M_MPF+M_EGG+M_NUTSD+M_SOY;	/*Calculate total meat intake from meat, poultry, & fish; egg; nuts and seeds; soy products*/
MBMAX=2.5*(DRXTKCAL/1000);	/*Create the Meat and Beans standard*/

 /*Legumes intake calculation*/
 /*Legumes intake counts as Meat and Beans until the standard is met, then the rest count as Total Vegetables*/

/*(a) If total meat intake is less than the Meat and Beans recommendation then 
  all Legumes go to Meat and Beans*/
IF ALLMEAT < MBMAX THEN DO;
   MEATLEG=LEGUMES*4;	/*Convert cup equivalents of Legumes to oz equivalents */
   NEEDMEAT=MBMAX-ALLMEAT;

   IF MEATLEG <= NEEDMEAT THEN DO;
      LEGTYPE='ALLMEAT ';
      ALLMEAT=ALLMEAT+MEATLEG;
      V_TOTAL=V_TOTAL;
      V_DOL=V_ORANGE+V_DRKGR;
   END; 

/*(b) Some Legumes go to Meat and Beans and the rest goes to Total Vegetables*/
   ELSE IF MEATLEG > NEEDMEAT THEN DO; 
      LEGTYPE='MEAT/VEG';
      EXTRMEAT=MEATLEG-NEEDMEAT;
      EXTRLEG=EXTRMEAT/4; 	/*Convert oz equivalents of Meat and Beans from Legumes back to cup equivalents*/
	  ALLMEAT=ALLMEAT+NEEDMEAT;
	  V_TOTAL=V_TOTAL+EXTRLEG;
	  V_DOL=V_ORANGE+V_DRKGR+EXTRLEG;
     END;
END; 

/*(c) If total meat intake exceeds the Meat and Beans standard, then all Legumes count as Total Vegetables*/
ELSE IF ALLMEAT >= MBMAX THEN DO;  
    LEGTYPE='ALLVEG';
    V_TOTAL=V_TOTAL+LEGUMES;
	V_DOL=V_ORANGE+V_DRKGR+LEGUMES;
END;

IF MBMAX > 0 THEN HEI8=10*(ALLMEAT/MBMAX);

/**Calculate HEI-2005 Total Vegetable non-truncated component score**/
/*Standard for maximum score is >=1.1 cup equiv/1000 kcal;
  no Vegetable intake, minimum score is zero*/
VMAX=1.1*(DRXTKCAL/1000);
VEGCUP=V_TOTAL;
IF VMAX > 0 THEN HEI3=5*(VEGCUP/VMAX);

/**Calculate HEI-2005 Dark Green and Orange Vegetables and Legumes non-truncated component score**/
/*Standard for maximum score is >=0.4 cup equiv/1000 kcal*/
DGMAX=.4*(DRXTKCAL/1000);
DGOCUP=V_DOL;
IF DGMAX > 0 THEN HEI4=5*(DGOCUP/DGMAX);

/**Calculate HEI-2005 Oils non-truncated component score**/
/*Standard for maximum score is >=12 grams/1000 kcal*/
OILMAX=12*(DRXTKCAL/1000);
IF OILMAX > 0 THEN HEI9=10*(DISCFAT_OIL/OILMAX);

/**Linear extrapolation for Saturated fat and Sodium non-truncated component scores: 
  Individuals with truncated score of >0 and <8 receive the same score; 
  Individuals with truncated score of >=8 will receive a linear extrapolated score 
  based on the scores of 0-8
**/

/**Calculate HEI-2005 Saturated Fat non-truncated component score**/
/*Standards for score of 8 is 10% of total kcal and score of zero is >=15%*/

IF DRXTKCAL > 0 THEN PCTSFAT=100*(DRXTSFAT*9)/DRXTKCAL; /*Calculate percent of calories from Saturated Fat*/

  /*truncated score is >0 and <8 for Saturated fat intake of 10%-15% of total kcal*/
  IF 10<PCTSFAT<15 then HEI10=8 - (8*(PCTSFAT-10)/5);

/**Calculate HEI-2005 Sodium non-truncated component score**/
/*Standards for score of 8 is 1.1 grams/1000 kcal and score of zero is >=2.0 grams/1000 kcal*/

IF DRXTKCAL > 0 THEN SODIDEN=(DRDTSODI*1000)/DRXTKCAL; /*Calcuate the sodium density*/
  /*truncated score is >0 and <8 for Sodium intake of 1.1 g - 2g/1000 kcal*/
  IF 1100<SODIDEN<2000 THEN HEI11=8 - (8 *(SODIDEN-1100)/(2000-1100));

/**Calculate HEI-2005 Calories from SoFAAS non-truncated component score**/
/*Standard for maximum score is <=20% total kcal, Maximum score is 20;
  >=50% total kcal, minimum score is zero*/

 /*Calculate SoFAAS Calories from Added sugars, solid fat, and alcoholic beverages*/
  ADDSUGC=16*ADD_SUG;		/*calories from added sugars*/
  SOLFATC=DISCFAT_SOL*9;	/*calories from solid fat*/
  
  IF ETHCAL < 0 THEN ETHCAL=0;
  IF BWCARBC < 0 THEN BWCARBC=0;
  EXFAAS=ADDSUGC+SOLFATC+ETHCAL+BWCARBC; /*total SoFAAS calories as in kcal*/
  
  ALCOHOLC=ETHCAL+BWCARBC;
  ADDSUGC_PERC=(ADDSUGC*100)/DRXTKCAL;
  ALCOHOLC_PERC=(ALCOHOLC*100)/DRXTKCAL;
  SOLFATC_PERC=(SOLFATC*100)/DRXTKCAL;

  IF DRXTKCAL > 0 THEN SOFA_PERC=(EXFAAS*100)/DRXTKCAL; /*Calculate SoFAAS as in %kcal*/

SOFAMIN=20;
SOFAMAX=50;
  HEI12= 20 - ( 20* (SOFA_PERC-SOFAMIN) / (SOFAMAX-SOFAMIN) );

run;

/*Calculate linear equations for Saturated fat and Sodium components based on the individuals with 
HEI-2005 component score of >0 and <8,
then extrapolate the equcations to the individuals with score >=8 or score <=0*/
data slop;
set HEI2005POP_0102SE_notrun;
if hei10 ^=.;
if hei11 ^=.;
run;
/*Calculate the linear equations*/
proc reg data=slop;
model HEI10=PCTSFAT;
model HEI11=SODIDEN;
run;

/*Apply the linear extrapolation of the equcations to the individuals with score >=8 or score <=0*/
data HEI2005POP_0102SE_notrunnew;
 set HEI2005POP_0102SE_notrun;
  if (PCTSFAT<=10 or PCTSFAT>=15) then do;
   HEI10=-1.60000*(PCTSFAT) + 24.00000;
  end;
  if (SODIDEN<=1100 or SODIDEN>=2000) then do;
	HEI11=  -0.00889*(SODIDEN)+  17.77778;
  end;

/**Calculate HEI-2005 total non-truncated score**/
/*Total HEI-2005 non-truncated score at the individual level is the 
  sum of 12 HEI-2005 non-truncated component scores*/
HEI2005new=HEI1+HEI2+HEI3+HEI4+HEI5+HEI6+HEI7+HEI8+HEI9+HEI10+HEI11+HEI12;

LABEL HEI2005new='Total Non-truncated HEI-2005 score at individual levels';
run;

/*Create population total to estimate the standard error of 
HEI-2005 total score for the population:

Population total = 
individual's total HEI-2005 non-truncated score x individual's total energy intake

*/
data pop0102seNEWpopwt;
 set HEI2005POP_0102SE_notrunnew;
 HEI2005kcal=HEI2005new*DRXTKCAL;
run;

proc sort data=pop0102seNEWpopwt; by SDMVSTRA SDMVPSU ; run;
proc ratio data=pop0102seNEWpopwt design=wr filetype=sas;
NEST SDMVSTRA SDMVPSU;
weight WTDRD1;
numer HEI2005kcal;
denom DRXTKCAL;
Setenv Labwidth=15 rowspce=0 colspce=2;
Print nsum="samzie" wsum="popsize" wxsum="total wted kcal" wysum="total wted HEI component score*intake kcal" 
		rhat="Prop. of score*kcal to total kcal" serhat="S.E. of Prop." lowrhat="lower 95%" uprhat="upper 95%"
		/nsumfmt=f15.0 wsumfmt=f15.0 wxsumfmt=f15.0 wysumfmt=f15.0 rhatfmt=f7.4 serhatfmt=f7.5 style=NCHS;
title1 "NHANES 2001-2002, SE for population total HEI-2005 score";
title2 "HEI-2005 non-truncated total score at the individual level";
title3 "Linear extrapolation of <=0 and >=8 based on <0 and >8 for Saturated Fat and Sodium components";
title4 "age 2+";
run;
/*Copy the standard error calculated in SUDAAN into the pink highlighted cell in 
HEI2005_NHANES 2001-2002PopScores.xls Excel worksheet
to obtain the 95% confidence interval for the population total HEI-2005 score*/